µSD Card
Data Corruption
To avoid any data loss or corrupting the SD card, users should disable all activity with the SD card before removing it from the RA6M5 Thing Plus.
The FATFileSystem library built into the Renesas-Arduino core, supports µSD cards with a FAT32 file system (i.e. SD cards up to 32GB in size).
- While users may be able to use cards with a higher storage capacity, we highly advise against it. As users may experience data loss due to a corrupt file system (i.e. SD cards with a storage capacity greater than 32GB are not meant to be formatted with a FAT32 file system).
SD Card - Test
The Renesas-Arduino core includes a built-in FATFileSystem library that controls the SD host interface. The library that supports SD cards with a FAT32 file system (i.e. SD cards up to 32GB in size). Users can find an example sketch in the File > Examples > Storage > TestSDCARD drop-down menu.
Optional Hardware
-
microSD Card - 1GB (Class 4)
COM-15107 -
microSD Card - 32GB (Class 10)
COM-19041 -
microSD USB Reader
COM-13004
TestSDCARD.ino
/*
Portenta H33 - TestSDCARD with Fat FS
The sketch shows how to mount an SDCARD and list its content.
The circuit:
- Portenta H33 + Portenta Breakout
created January 31th, 2023
by Daniele Aimo
This example code is in the public domain.
*/
#include <vector>
#include <string>
#include "SDCardBlockDevice.h"
#include "FATFileSystem.h"
#define TEST_FS_NAME "fs"
#define TEST_FOLDER_NAME "TEST_FOLDER"
#define TEST_FILE "test.txt"
#define DELETE_FILE_DIMENSION 150
SDCardBlockDevice block_device(PIN_SDHI_CLK, PIN_SDHI_CMD, PIN_SDHI_D0, PIN_SDHI_D1, PIN_SDHI_D2, PIN_SDHI_D3, PIN_SDHI_CD, PIN_SDHI_WP);
FATFileSystem fs(TEST_FS_NAME);
std::string root_folder = std::string("/") + std::string(TEST_FS_NAME);
std::string folder_test_name = root_folder + std::string("/") + std::string(TEST_FOLDER_NAME);
std::string file_test_name = folder_test_name + std::string("/") + std::string(TEST_FILE);
void setup() {
/*
* SERIAL INITIALIZATION
*/
Serial.begin(9600);
while(!Serial) {
}
/* list to store all directory in the root */
std::vector<std::string> dir_list;
Serial.println();
Serial.println("##### TEST SD CARD with FAT FS");
Serial.println();
/*
* MOUNTING SDCARD AS FATFS filesystem
*/
Serial.println("Mounting SDCARD...");
int err = fs.mount(&block_device);
if (err) {
// Reformat if we can't mount the filesystem
// this should only happen on the first boot
Serial.println("No filesystem found, formatting... ");
err = fs.reformat(&block_device);
}
if (err) {
Serial.println("Error formatting SDCARD ");
while(1);
}
/*
* READING root folder
*/
DIR *dir;
struct dirent *ent;
int dirIndex = 0;
Serial.println("*** List SD CARD content: ");
if ((dir = opendir(root_folder.c_str())) != NULL) {
while ((ent = readdir (dir)) != NULL) {
if(ent->d_type == DT_REG) {
Serial.print("- [File]: ");
}
else if(ent->d_type == DT_DIR) {
Serial.print("- [Fold]: ");
dir_list.push_back(ent->d_name);
}
Serial.println(ent->d_name);
dirIndex++;
}
closedir (dir);
}
else {
// Could not open directory
Serial.println("Error opening SDCARD\n");
while(1);
}
if(dirIndex == 0) {
Serial.println("Empty SDCARD");
}
bool found_test_folder = false;
/*
* LISTING CONTENT of the first level folders (the one immediately present in root folder)
*/
if(dir_list.size()) {
Serial.println();
Serial.println("Listing content of folders in root: ");
}
for(unsigned int i = 0; i < dir_list.size(); i++) {
if(dir_list[i] == TEST_FOLDER_NAME) {
found_test_folder = true;
}
Serial.print("- ");
Serial.print(dir_list[i].c_str());
Serial.println(":");
std::string d = root_folder + std::string("/") + dir_list[i];
if ((dir = opendir(d.c_str())) != NULL) {
while ((ent = readdir (dir)) != NULL) {
if(ent->d_type == DT_REG) {
Serial.print(" - [File]: ");
}
else if(ent->d_type == DT_DIR) {
Serial.print(" - [Fold]: ");
}
Serial.println(ent->d_name);
}
closedir (dir);
}
else {
Serial.print("ERROR OPENING SUB-FOLDER ");
Serial.println(d.c_str());
}
}
/*
* CREATING TEST FOLDER (if does not exist already)
*/
err = 0;
if(!found_test_folder) {
Serial.println("TEST FOLDER NOT FOUND... creating folder test");
err = mkdir(folder_test_name.c_str(), S_IRWXU | S_IRWXG | S_IRWXO);
if(err != 0) {
Serial.print("FAILED folder creation with error ");
Serial.println(err);
}
}
/*
* READING TEST FILE CONTENT
*/
if(err == 0) {
int file_dimension = 0;
FILE* fp = fopen(file_test_name.c_str(), "r");
if(fp != NULL) {
Serial.print("Opened file: ");
Serial.print(file_test_name.c_str());
Serial.println(" for reading");
fseek(fp, 0L, SEEK_END);
int numbytes = ftell(fp);
fseek(fp, 0L, SEEK_SET);
Serial.print("Bytes in the file: ");
Serial.println(numbytes);
file_dimension = numbytes;
if(numbytes > 0) {
Serial.println();
Serial.println("-------------------- START FILE CONTENT --------------------");
}
for(int i = 0; i < numbytes; i++) {
char ch;
fread(&ch, sizeof(char), 1, fp);
Serial.print(ch);
}
if(numbytes > 0) {
Serial.println("--------------------- END FILE CONTENT ---------------------");
Serial.println();
}
else {
Serial.println("File is EMPTY!");
Serial.println();
}
fclose(fp);
}
else {
Serial.print("FAILED open file ");
Serial.println(file_test_name.c_str());
}
/*
* DELETE FILE IF THE File dimension is greater than 150 bytes
*/
if(file_dimension > DELETE_FILE_DIMENSION) {
Serial.println("Test file reached the delete dimension... deleting it!");
if(remove(file_test_name.c_str()) == 0) {
Serial.println("TEST FILE HAS BEEN DELETED!");
}
}
/*
* APPENDING SOMETHING TO FILE
*/
fp = fopen(file_test_name.c_str(), "a");
if(fp != NULL) {
Serial.print("Opened file: ");
Serial.print(file_test_name.c_str());
Serial.println(" for writing (append)");
char text[] = "This line has been appended to file!\n";
fwrite(text, sizeof(char), strlen(text), fp);
fclose(fp);
}
else {
Serial.print("FAILED open file for appending ");
Serial.println(file_test_name.c_str());
}
/*
* READING AGAIN FILE CONTENT
*/
fp = fopen(file_test_name.c_str(), "r");
if(fp != NULL) {
Serial.print("Opened file: ");
Serial.print(file_test_name.c_str());
Serial.println(" for reading");
fseek(fp, 0L, SEEK_END);
int numbytes = ftell(fp);
fseek(fp, 0L, SEEK_SET);
Serial.print("Bytes in the file: ");
Serial.println(numbytes);
if(numbytes > 0) {
Serial.println();
Serial.println("-------------------- START FILE CONTENT --------------------");
}
for(int i = 0; i < numbytes; i++) {
char ch;
fread(&ch, sizeof(char), 1, fp);
Serial.print(ch);
}
if(numbytes > 0) {
Serial.println("--------------------- END FILE CONTENT ---------------------");
Serial.println();
}
else {
Serial.println("File is EMPTY!");
Serial.println();
}
fclose(fp);
}
else {
Serial.print("FAILED open file for appending ");
Serial.println(file_test_name.c_str());
}
}
}
void loop() {
// Empty
}